#include "../ColorPalette.hls"
#include "../DeathScreen.hls"
#include "../MipLevels.hls"
#include "../FogOfWar/FogOfWar_PS.hls"
#include "ColorRemap.hls"

sampler TEXTURE     : register (s0);
#ifdef  MULTIPASS
sampler TEXTUREMULT     : register  (s3);
#endif
sampler PARTICLE_COLOR_TEXTURE : register (s1);

#if defined(COLORPALETTE_COLORBLIND)
   float4 APPLY_TEAM_COLOR_CORRECTION : register(c11);
#endif

struct PS_IN
{
    float4  color0          : TEXCOORD0;    // N.B. colors can be > 1 (e.g. mod2x), so use a full interpolator and not COLOR0 which saturates on ps_2_0
    float4  uv0_uv1         : TEXCOORD1;
    float4  uvFOW_uvAlpha   : TEXCOORD2;
};

void main( in PS_IN input, out float4 out_color0:COLOR0 )
{
    float2 uv0      = input.uv0_uv1.xy;
    float2 uv1      = input.uv0_uv1.zw;
#ifndef DISABLE_FOW
    float2 uvFOW    = input.uvFOW_uvAlpha.xy;
#endif
    float2 uvAlpha  = input.uvFOW_uvAlpha.zw;
    
    float4 color_texel = tex2D(TEXTURE, uv0);
    float4 alpha_texel = tex2D(TEXTURE, uvAlpha);

#ifdef PALETTIZE_TEXTURES
    // remap textures according to palettization settings
    color_texel.rgb = ColorizeMainTexture(color_texel).rgb;
#endif
    
#ifdef  MULTIPASS
    float4 particle_color_texel = tex2D(TEXTUREMULT, uv1);
#else
    float4 particle_color_texel = tex2D(PARTICLE_COLOR_TEXTURE, uv1);
#endif  

    out_color0.rgb  = color_texel.rgb * input.color0.rgb * particle_color_texel.rgb;
    out_color0.a    = alpha_texel.a * input.color0.a * particle_color_texel.a;

#ifdef COLORPALETTE_COLORBLIND
    if (APPLY_TEAM_COLOR_CORRECTION.r != 0.0f)
    {
        ApplyColorCorrectionColorblind(out_color0);
    }
#endif 
    
#ifndef DISABLE_FOW
    float4 fowFactors = GetFogOfWarFactors(uvFOW);
    // Apply FOW to final result
    // NOTE:  This ignores the FowOverlay texture tint and assumes the FoW is black
    out_color0.rgb *= fowFactors.a;
#endif

    out_color0.rgb = ApplyMipColorsVisualization(out_color0.rgb, uv0);
}
