/////////////////////////////////////////////////////////////////////////////////////
// Constants
/////////////////////////////////////////////////////////////////////////////////////

#ifdef POINTLIGHTS
	#ifdef SHADOW_ENABLE
		column_major float4x4 SHADOW_PROJECTION_MATRIX0	: register(c8);
		column_major float4x4 SHADOW_PROJECTION_MATRIX1	: register(c12);
		column_major float4x4 SHADOW_PROJECTION_MATRIX2	: register(c16);
		column_major float4x4 SHADOW_PROJECTION_MATRIX3	: register(c20);
	#endif
#elif defined(COMPUTE_AO)
	column_major float4x4 SHADOW_PROJECTION_MATRIX	: register(c8);
#else
	float4 AO_MAP_UV_SCALEOFFS						: register(c8);
	column_major float4x4 SHADOW_PROJECTION_MATRIX 	: register(c9);
#endif

struct VERTEX
{
	float3 m_Position : POSITION;
	float3 m_Normal   : NORMAL;
	float2 m_TexCoord : TEXCOORD0;	//output atlas UV coordinates (in screen space).
	float4 m_Color0   : COLOR0;
};

struct INTERPOLANTS
{
	float4 m_Position   : POSITION;
	float3 m_PositionWS : TEXCOORD0;
	float3 m_NormalWS   : TEXCOORD1;
#if defined(POINTLIGHTS)
	#ifdef SHADOW_ENABLE
		float4 m_ShadowProj0 : TEXCOORD2;
		float4 m_ShadowProj1 : TEXCOORD3;
		float4 m_ShadowProj2 : TEXCOORD4;
		float4 m_ShadowProj3 : TEXCOORD5;
	#endif
#elif defined(COMPUTE_AO)
	float4 m_ShadowProj  : TEXCOORD2;
#else
	float4 m_Color		 : COLOR0;
	float4 m_ShadowProj  : TEXCOORD2;
#endif
};

/////////////////////////////////////////////////////////////////////////////////////
// Shader
/////////////////////////////////////////////////////////////////////////////////////
void main(VERTEX vertex, out INTERPOLANTS interpolants)
{
	// Output homogeneous position
	float2 inTC = vertex.m_TexCoord.xy / 4096.0f;
	interpolants.m_Position = float4(inTC.x*2.0f-1.0f, 1.0f-2.0f*inTC.y, 1.0f, 1.0f);
	// Output world space position and normal for per-pixel lighting.
	interpolants.m_PositionWS = vertex.m_Position.xyz;
	interpolants.m_NormalWS   = normalize( vertex.m_Normal.xyz*2.0f - 1.0f );
	
#if defined(POINTLIGHTS)
	#ifdef SHADOW_ENABLE
		float4 pos = float4(vertex.m_Position, 1.0f);
		interpolants.m_ShadowProj0 = mul( pos, SHADOW_PROJECTION_MATRIX0 );
		interpolants.m_ShadowProj1 = mul( pos, SHADOW_PROJECTION_MATRIX1 );
		interpolants.m_ShadowProj2 = mul( pos, SHADOW_PROJECTION_MATRIX2 );
		interpolants.m_ShadowProj3 = mul( pos, SHADOW_PROJECTION_MATRIX3 );
	#endif
#elif defined(COMPUTE_AO)
	float4 pos = float4(vertex.m_Position, 1.0f);
	interpolants.m_ShadowProj = mul( pos, SHADOW_PROJECTION_MATRIX );
#else
	interpolants.m_Color = vertex.m_Color0.VCOLORSWIZZLE;
	
	float4 pos = float4(vertex.m_Position, 1.0f);
	interpolants.m_ShadowProj = mul( pos, SHADOW_PROJECTION_MATRIX );
#endif
}
