/////////////////////////////////////////////////////////////////////////////////////
// Constants
/////////////////////////////////////////////////////////////////////////////////////

#ifdef POINTLIGHTS
	float4 lightPosScale[4]  : register(c0);
	float4 lightColor0[4]    : register(c4);
	float4 lightColor1[4]    : register(c8);
	float4 lightAtten[4]	 : register(c12);
#else
	float3 directionalVector : register(c0);
	float3 directionalColor0 : register(c1);
	float3 directionalColor1 : register(c2);
	float3 ambientColor		 : register(c3);
	float4 lightPosScale	 : register(c4);
	
	float4 skyAO_color0		 : register(c5);
	float4 skyAO_color1		 : register(c6); //sky AO color position.
	
	float4 sunAO_color0		 : register(c7);
	float4 sunAO_color1		 : register(c8); //sun AO color position.
#endif

#ifdef POINTLIGHTS
	#ifdef SHADOW_ENABLE
		sampler SHADOWMAP0 : register(s0);
		sampler SHADOWMAP1 : register(s1);
		sampler SHADOWMAP2 : register(s2);
		sampler SHADOWMAP3 : register(s3);
	#endif
#else
	sampler AO_MAP    : register(s0);
	sampler SHADOWMAP : register(s1);
	samplerCUBE LIGHT_CUBE : register(s2);
#endif

struct FRAGMENT
{
	float4 m_Color0 : COLOR0;
};

struct INTERPOLANTS
{
	float4 m_Position   : POSITION;
	float3 m_PositionWS : TEXCOORD0;
	float3 m_NormalWS   : TEXCOORD1;
#ifdef POINTLIGHTS
	#ifdef SHADOW_ENABLE
		float4 m_ShadowProj0 : TEXCOORD2;
		float4 m_ShadowProj1 : TEXCOORD3;
		float4 m_ShadowProj2 : TEXCOORD4;
		float4 m_ShadowProj3 : TEXCOORD5;
	#endif
#elif defined(COMPUTE_VPATCH_AO)
	float4 m_Color		 : COLOR0;
	float4 m_ShadowProj  : TEXCOORD2;
#else
	float4 m_ShadowProj  : TEXCOORD2;
	float2 m_AO_Map_UV	 : TEXCOORD3;
#endif
};


/////////////////////////////////////////////////////////////////////////////////////
// Shader
/////////////////////////////////////////////////////////////////////////////////////

FRAGMENT main(INTERPOLANTS interpolants)
{
	FRAGMENT fragment;
	fragment.m_Color0 = float4(0,0,0,1);

	// Apply per-pixel lighting.
	float3 N = normalize( interpolants.m_NormalWS );
	
#ifdef POINTLIGHTS
	float3 L0 = interpolants.m_PositionWS*lightPosScale[0].w + lightPosScale[0].xyz;
	float3 L1 = interpolants.m_PositionWS*lightPosScale[1].w + lightPosScale[1].xyz;
	float3 L2 = interpolants.m_PositionWS*lightPosScale[2].w + lightPosScale[2].xyz;
	float3 L3 = interpolants.m_PositionWS*lightPosScale[3].w + lightPosScale[3].xyz;
	
	float4 lightDepth = float4( -L0.y, -L1.y, -L2.y, -L3.y );
	float4 d  = float4( dot(L0,L0), dot(L1,L1), dot(L2,L2), dot(L3,L3) );
	d = sqrt(d);
	float4 rcpD = 1.0f/d;
	L0 *= rcpD.x;
	L1 *= rcpD.y;
	L2 *= rcpD.z;
	L3 *= rcpD.w;
	
	float4 diffuse;
	float4 diffuseResponse = float4( dot(L0,-N), dot(L1,-N), dot(L2,-N), dot(L3,-N) );
	diffuseResponse = max( diffuseResponse, 0 );
	diffuse.x = saturate(d.x*lightAtten[0].x+lightAtten[0].y);
	diffuse.y = saturate(d.y*lightAtten[1].x+lightAtten[1].y);
	diffuse.z = saturate(d.z*lightAtten[2].x+lightAtten[2].y);
	diffuse.w = saturate(d.w*lightAtten[3].x+lightAtten[3].y);
	
	//A + R*(B-A) -> lightColor0 = A, lightColor1 = B - A
	float4 C0 = (lightColor0[0] + lightColor1[0]*diffuse.x)*diffuseResponse.x;
	float4 C1 = (lightColor0[1] + lightColor1[1]*diffuse.y)*diffuseResponse.y;
	float4 C2 = (lightColor0[2] + lightColor1[2]*diffuse.z)*diffuseResponse.z;
	float4 C3 = (lightColor0[3] + lightColor1[3]*diffuse.w)*diffuseResponse.w;
	
#ifdef SHADOW_ENABLE
	float4 shadow;
	shadow.x = tex2Dproj(SHADOWMAP0, interpolants.m_ShadowProj0).x;
	shadow.y = tex2Dproj(SHADOWMAP1, interpolants.m_ShadowProj1).x;
	shadow.z = tex2Dproj(SHADOWMAP2, interpolants.m_ShadowProj2).x;
	shadow.w = tex2Dproj(SHADOWMAP3, interpolants.m_ShadowProj3).x;
	
	float over_darkening_factor = 160.0f;
	float4 shIntens = saturate( exp2( over_darkening_factor * (shadow - lightDepth) ) );
	diffuse = saturate(diffuse*shIntens);
#endif
	
	fragment.m_Color0  = diffuse.x*C0;
	fragment.m_Color0 += diffuse.y*C1;
	fragment.m_Color0 += diffuse.z*C2;
	fragment.m_Color0 += diffuse.w*C3;
#elif defined(COMPUTE_VPATCH_AO)
	float3 L = interpolants.m_PositionWS.xyz*lightPosScale.w + lightPosScale.xyz;
	float depth = saturate( dot(L, -directionalVector.xyz) );

	float shadow = tex2Dproj(SHADOWMAP, interpolants.m_ShadowProj).x;
	float over_darkening_factor = 160.0f;
	float shIntens = saturate( exp2( over_darkening_factor * (shadow - depth) ) );

	float ao = interpolants.m_Color.a;
	float ao_power = saturate( pow(ao, 4.0f) );
	
	float3 skylight_ao, sunlight_ao;
	skylight_ao = lerp(skyAO_color0.rgb, skyAO_color1.rgb, saturate(ao_power/skyAO_color1.a));
	skylight_ao = lerp(skylight_ao,  1.0f, saturate((ao_power-skyAO_color1.a)/(1.0f-skyAO_color1.a)));
		
	sunlight_ao = lerp(sunAO_color0.rgb, sunAO_color1.rgb, saturate(ao_power/sunAO_color1.a));
	sunlight_ao = lerp(sunlight_ao,  1.0f, saturate((ao_power-sunAO_color1.a)/(1.0f-sunAO_color1.a)));
	
	float3 skylight = texCUBE(LIGHT_CUBE, N).rgb * 0.5f;
	
	float  d = saturate( dot(N, directionalVector) );
	float3 C = lerp(directionalColor1.rgb, directionalColor0.rgb, d);
	fragment.m_Color0.rgb += d * C * sunlight_ao * shIntens;
	fragment.m_Color0.rgb += skylight*skylight_ao;
	
	fragment.m_Color0.rgb *= 0.5f;
#else
	float3 L = interpolants.m_PositionWS.xyz*lightPosScale.w + lightPosScale.xyz;
	float depth = saturate( dot(L, -directionalVector.xyz) );

	float shadow = tex2Dproj(SHADOWMAP, interpolants.m_ShadowProj).x;
	float over_darkening_factor = 160.0f;
	float shIntens = saturate( exp2( over_darkening_factor * (shadow - depth) ) );
	
	float ao = tex2D(AO_MAP, interpolants.m_AO_Map_UV).x;
	float ao_power = saturate( pow(ao, 4.0f)*0.125f );
	
	float3 skylight_ao, sunlight_ao;
	skylight_ao = lerp(skyAO_color0.rgb, skyAO_color1.rgb, saturate(ao_power/skyAO_color1.a));
	skylight_ao = lerp(skylight_ao,  1.0f, saturate((ao_power-skyAO_color1.a)/(1.0f-skyAO_color1.a)));
		
	sunlight_ao = lerp(sunAO_color0.rgb, sunAO_color1.rgb, saturate(ao_power/sunAO_color1.a));
	sunlight_ao = lerp(sunlight_ao,  1.0f, saturate((ao_power-sunAO_color1.a)/(1.0f-sunAO_color1.a)));
	
	float3 skylight = texCUBE(LIGHT_CUBE, N).rgb * 0.5f;
		
	float  d = saturate( dot(N, directionalVector) );
	float3 C = lerp(directionalColor1.rgb, directionalColor0.rgb, d);
	fragment.m_Color0.rgb += d * C * sunlight_ao * shIntens;
	fragment.m_Color0.rgb += skylight*skylight_ao;
	
	fragment.m_Color0.rgb *= 0.5f;
#endif
	fragment.m_Color0     = saturate( fragment.m_Color0 );
	
	return fragment;
}
